With this Customized Invoice Tally Prime TDL we can provide professional invoices to our customers, even want to create Normal Invoice or E- Invoice. In these invoice format can show your logo and company details like address and GST and QR in top of Invoice. And also change Item listing in header colors and font.
This is best and good looking invoice format for both Normal & E-Invoice. With Tally Definition Language (TDL), users can further personalize their invoices to meet specific business needs
Customized Invoice Tally Prime TDL:
Normal invoices are the standard format used for billing purposes. This Invoice TDL allows users to customize these invoices extensively. With this Normal & E-Invoice Format TDL, businesses can:
Adding Company Logo and Details:
Incorporate your company logo, address, GST details, and other pertinent information at the top of the invoice for a personalized touch.
QR Code Integration:
In normal invoices adding QR code of Bank Payment detail and and in E- Invoice, E- Invoice QR code along with Bank Payment QR code.
Invoice Details and Party Details in Horizontal form:
To save extra spaces of invoice changed invoice details like, Invoice number, Date, references etc. and Buyer and Consignee Details in Horizontal form in Invoice.
Changing Item Listing looks:
Modify the item listing section’s colors, fonts, and layout in the header to align with your brand aesthetics.
Also checkout Manual Books TDL for Tally Prime
Customized E- Invoice and Normal Invoice TDL code:
Tally Prime’s flexibility combined with TDL empowers users to create tailored invoices that reflect their brand identity and meet regulatory requirements.
[#Part: EXPINV SaleTopLeft]
Height : If ($$InExportMode OR $$InMailAction OR $$InUploadAction) AND ($$IsSysNameEqual:Excel:##SVExportFormat OR $$IsSysNameEqual:HTML:##SVExportFormat) THEN +
(10 + 10 + @WithOrderVch + @WithOrderTerms + @WithBuyer + @WithCountry) ELSE +
(10 + 10 + @WithOrderVch + @WithOrderTerms + @WithBuyer + @WithCountry) % page
Delete: Parts: EXPINV Company
[#Form: Printed Invoice]
Add:Parts:LWCMPDetails,LWTaxTitle,LearnwellEQR
[Part:LWTaxTitle]
Add:Line:LwTTLine
Border:thin bottom
Space Top:.5
[Line:LwTTLine]
Add:Field:LWTTF
Border:Thin Top
[Field:LWTTF]
Set as:"Tax Invoice"
Full Width:Yes
Align:Centre
Style:Invstyle
[Style:Invstyle]
Use: Normal Bold
Height:15
[Part:LWCMPDetails]
Add:Parts:CMPLogo,CMPdtl,LWSCPay
Space Bottom:.5
Width:100% page
[Part:CMPLOGO]
Part :LearnWellLOGO
Vertical : Yes
[Part :LearnWellLOGO]
Horizontal Alignment :Left
Vertical : No
Lines :LWLG
Graph Type: ##SALogoPath
Height : 12% page
Width : 15% Page
[Line :LWLG]
Field :LWLGF
[Field :LWLGF]
Set As : ""
[Part:CMPdtl]
Lines:LWCMPName,LWCMPAdd
Repeat:LWCMPAdd:CompanyAddress
[Line:LWCMPName]
Field:LWCMPName
[Field:LWCMPName]
Use:name field
Set as:@@CMPMailNAme
Full Width:Yes
Align:Centre
Style:Cmpstyle
[Line:LWCMPAdd]
Field:LWCMPAdd
[Field:LWCMPAdd]
Set as:$address
Align:Center
Full Width:Yes
Style:ADDStyle
[Style:Cmpstyle]
Use: Normal Bold
Height:20
[Style:ADDStyle]
Height:10
Use:Normal
[#Part: EXPINV Signature]
Delete:Border
[#Part: EXPINV Column]
Border:Thick Box
Delete:Line:EXPINV Column2
Local : Field : Default : Style :Normal Bold
Local : Field : Default : Print FG :White
Print BG:Black
[#line : EXPINV invdetails]
option:bg print:@@oddline
[!line:bg print]
local : field : default : print bg :Light grey
[system:formulae]
OddLine : $$IsOdd:$$Line
;---------------------------------------------
[#Part: EXPINV OpPageBreak]
Delete: Parts:EXPINV Title
Delete:Parts:EXPINV Leading
Add:Parts:Before:EXPINV Column:LearnwellInvNo1,LearnwellInvNo
[#Part : Expinv Rightsign]
Delete : Bottom Parts
Add:Bottom Part:EXPINV Signature
[Part:LearnwellEQR]
Add:Part:LWEInv1,LWEInvQR,LearnwellBankQR
Border:Thin box
Invisible: NOT ##SAGSTWithQRInfo OR $$IsEmpty:@@eInvoiceQRCValue OR NOT @@IsVchGSTeInvAppl
[Part:LWEInv1]
Line: LWExpinv IRN, LWExpinv AckNo, LWExpinv AckDate
Local: Line : LWExpinv AckNo : Space top : 0.10
Local: Line : LWExpinv AckDate : Space top : 0.10
Space Top:.5
[Line: LWExpinv IRN]
Use : LWeInv IRN Details Template
Local: Field: Medium Prompt : Set as : $$LocaleString:"IRN"
Local: Field: Name Field : Set as : @@GSTeInvIRN
Local: Field: Name Field : Width : 30% Page
Local: Field: Name Field : Line : 03
[Line: LWExpinv AckNo]
Use : LWeInv IRN Details Template
Local: Field: Medium Prompt : Set as : $$LocaleString:"Ack No."
Local: Field: Name Field : Set as : If ##IseInvPSPrintAfterSave Then ##eInvPSAckNo Else $IRNAckNo
[Line: LWExpinv AckDate]
Use : LWeInv IRN Details Template
Space Bottom: 0.25
Local: Field: Medium Prompt : Set as : $$LocaleString:"Ack Date"
Local: Field: Name Field : Set as : If ##IseInvPSPrintAfterSave Then $$String:##eInvPSAckDate Else $$String:$IRNAckDate
[Line: LWeInv IRN Details Template]
Field: Medium Prompt, Name Field
Local: Field: Medium Prompt : Width : 4
Local: Field: Medium Prompt : Style : Small
Local: Field: Name Field : Style : Small Bold
[Part:LWEInvQR]
Part:LWeInvoice QRC Title2, LWeInvoice QRC Title
Vertical: Yes
[Part: LWeInvoice QRC Title]
Line: LWeInvoice QRC Title
[Line: LWeInvoice QRC Title]
Field: LWeInvoice QRC Title
Space Bottom: 0.5
[Part: LWeInvoice QRC Title2]
QRCode: @@eInvoiceQRCValue : Yes
Line: LWeInvoice QRC Title2
Width: 20% page
Height: 10% Page
[Line: LWeInvoice QRC Title2]
Field: Info Field
[Field: LWeInvoice QRC Title]
Use : Simple Field
Set as: $$LocaleString:"e-Invoice"
Style: Small Bold
Width: Normal
[Part :LearnWellBankQR]
Parts :EXPINV BankDetails,LearnWellQrP
Border:Thin box
Space Top:.5
[Part :LearnWellQrP]
Part :LearnWellQRCode
Vertical : Yes
[Part :LearnWellQRCode]
Horizontal Alignment : Right
Vertical : No
Lines :LWQrL
QR code: ("upi://pay?pa=9131810293@ybl&pn=AshishKumarSingh&tn=Bill No. "+$$String:$voucherNumber) : True
Height : 12% page
Width : 15% Page
[Line :LWQrL]
Field :LWQrF
[Field :LWQrF]
Set As : ""
[Part:LWSCPay]
Part :LearnWellQRIn,qrtxt
Vertical : Yes
Invisible:NOT $$IsEmpty:@@eInvoiceQRCValue
[Part :LearnWellQRIn]
Lines :LWQrLn
QR code: ("upi://pay?pa=9131810293@ybl&pn=AshishKumarSingh&tn=Bill No."+$$String:$voucherNumber) : True
Height : 8% page
Width : 12% Page
[Line :LWQrLn]
Field :LWQrFn
[Field :LWQrFn]
Set As : ""
[Part:qrtxt]
Line:as
[Line:as]
Field:as
[Field:as]
Use:name field
Set as:"Scan to Pay"
[Part:LearnwellInvNo]
Parts:EXPINV Consignee, EXPINV ConsigneeContact, EXPINV Buyer, EXPINV Contact
Bottom Parts: EXPINV Country
Vertical : No
Border:Thin box
[Part:LearnwellInvNo1]
Parts:LWBSLeft,LWBSMiddle,LWBSRight
Vertical:Yes
Border:thin box
[Part:LWBSLeft]
Parts : EXPINV Number,EXPINV Date,EXPINV SupplierRef,EXPINV DelNote,EXPINV ShipDate
Vertical : No
[Part:LWBSRight]
Parts : EXPINV DueDate, EXPINV OtherRef, +
JWInOutInv MotorVehicleNo, +
EXPINV PlaceOfRcpt, EXPINV PortDischarge, JMInOutInv ProcessingDuration
Vertical : No
[Part:LWBSMiddle]
Parts: EXPINV OrderNumber, EXPINV OrderDate, EXPINV ShipDoc,EXPINV Destination,JWMTIn ChallanNo,EXPINV PreCarr, EXPINV Vessel, EXPINV PortLoading, JMInOutInv EmptyPart
Border:thin box
Invoice TDL:
HOW TO USE TDL CODE:
- Copy or Download above TDL code and create a text file.
- Save text file and load in Tally
- Goto print and sales invoice, and enable bank details etc. (watch the below video for more details).
- You can see changed invoice format.
This is best free TDL to have in your Tally. Must have TDL file for Tally ERP9 and Tally Prime that can use it for lifetime. This free TDL Code will perfectly work with Tally Prime.
Customized Invoice Tally Prime TDL Video:
See the below video to learn how to use Custom Invoice TDL in Tally Prime:
Watch above videos to learn :
- How to use TDL files in Tally.
- How to add own details in Tally TDL
- How to create TDL file.
- How to customize invoice with TDL.
- More videos related to free TDL files on youtube/learnwell
- Get More TDL files on https://e2t.in/
FOLLOW THE BELLOW INSTRUCTIONS TO LOAD TDL FILE IN TALLY:
- Make a Text file of above code
- Save it in to your computer
- Copy the text file path including Name and extension (as – C:\Users\HP\Desktop\rec\InvoiceTDL.txt)
- Open Tally Prime Software
- Click on Help and click on TDL & Addon (for Tally Prime)
- Press F4 (to open a Box)
- Set Load TDL file on Startup – Yes
- Paste The path in blank space
- Press enter and save
- Now your Invoice TDL file for Tally Prime is ready to use.
By leveraging Tally Prime’s TDL capabilities, you can craft professional and personalized invoices for both Normal and E-Invoice formats. Incorporating your company logo, details, QR codes, and adjusting the visual aspects of the item listing allows you to present a consistent brand image while meeting the necessary invoicing standards. This level of customization not only enhances the professionalism of your invoices but also helps strengthen your brand identity with every interaction.
